!------------------------------------------------------

fini
/clear
/title, Static analysis of 3D coated

/prep7

!Units system use SI system: ton, mm,N, ms,MPa, density(ton/mm3), Stress: (MPa)

!material properties (C45)

mp,ex,1,2.1e5  !Young's modulus (MPa) 
mp,nuxy,1,0.3   !Poisson's ratios
mp,dens,1,8.03e-9 !density(ton/mm3)

!material properties (interlayer-niken)

mp,ex,3,2e5  !Young's modulus (Mpa) 
mp,nuxy,3,0.31  !Poisson's ratios
mp,dens,3,8.908e-9 !density(ton/mm3)


!material properties (coating-chromium)

mp,ex,4,2.79e5  !Young's modulus (Mpa) 
mp,nuxy,4,0.21   !Poisson's ratios
mp,dens,4,7.19e-9 !density(ton/mm3)



!element type (SOLID187- 3-D 10-Node Tetrahedral Structural Solid )
 et,1,solid186
 ET,2,MASS21 

 ! 20-node bricks
 et,3,solid186
 et,4,solid186

!*  
KEYOPT,2,1,0
KEYOPT,2,2,0
KEYOPT,2,3,0
R,1, , , , , , ,


!keypoints for subtrate
 k,1,0  ,  0 ,,
 k,2,0  ,  6 ,,
 k,3,15.85, 5,,
 k,4,44.15, 5,,
 k,5,60, 6,,
 k,6,60, 0,,
 k,7,14.20,104.99,,
 k,8,45.8,104.99,,

!keypoints for interlayer
 k,9,0  , 6.01 ,,
 k,10,15.85, 5.01,,
 k,11,44.15, 5.01,,
 k,12,60, 6.01,,

!keypoints for coating
 k,13,0  , 6.03 ,,
 k,14,15.85, 5.03,,
 k,15,44.15, 5.03,,
 k,16,60, 6.03,,

!lines for substrate
 lstr,1,2
 arc,2,3,7, 100
 lstr,3,4
 arc,4,5,8, 100
 lstr,5,6
 lstr,6,1

!lines for interlayer
 lstr,2,9
 arc,9,10,7, 99.99
 lstr,10,11
 arc,11,12,8, 99.99
 lstr,12,5

!lines for coating
 lstr,9,13
 arc,13,14,7, 99.97
 lstr,14,15
 arc,15,16,8, 99.97
 lstr,16,12
 lplot,all

!area
 al,1,2,3,4,5,6       !substrate
 al,2,3,4,11,10,9,8,7 !interlayer
 al,12,13,14,15,16,10,9,8 !coating

 aplot,all

!rotate
 vrotat,1, , , , , ,1,6,360, ,!substrate
 vrotat,2, , , , , ,1,6,360, ,!interlayer
 vrotat,3, , , , , ,1,6,360, ,!coating
 vplot,all

vglue, all

! additionally cut the volumes to allow them to be swept
kwpave, 3
wprota,,, 90
vsbw, all
kwpave, 4
vsbw, all
wpcsys, -1

! put substrate, interlayer and coating volumes into separate components
! and assign them mat and type
csys, 6
lsel,, loc, x,
asll
vsla
cm, v_sub, volu
vatt, 1,, 1
aslv

vsla
cmsel,u, v_sub
cm, v_inter, volu
vatt, 3,, 3
aslv
vsla

cmsel,u, v_sub
cmsel,u, v_inter
cm, v_coat, volu
vatt, 4,, 4
alls
csys, 0




cmsel,, v_sub
type,1  !element type  
mshape,1,3D ! hexagonal el.
esize,2.0
mshkey,0
vmesh,all

cmsel,, v_inter
vsweep, all

cmsel,, v_coat
vsweep, all




! load angular velocity
omega,315,0,0  ! (3000 V/p)


! load moment on keypoint

!select MASS21 as current
TYPE,   2   
REAL,       1      
TSHAP,LINE  
!*  
!*  
ksel,,kp,,1 
nslk
ar21 = ndnext(0)
E, ar21
F,all,Mz,-500

asel,,loc,x, kx(1)
nsla,,1
cerig, ar21, all, uxyz
   
ksel,,kp,,6 
nslk
ar21 = ndnext(0)  
E, ar21  
F,all,Mz,500

asel,,loc,x, kx(6)
nsla,,1
cerig, ar21, all, uxyz

alls

! apply boundary x,y,z axis 

DK,1,uy,0, , ,uz,ux,ROTX  ! fixed ux,uy,uz keypoint 1,
DK,6,uy,0, , ,uz,ux  ! fixed ux,uy,uz keypoint 6,


!*return,-1
save
finish 

 /sol
/status,solu
solve


/post1
plnsol,u,sum,1,1 ! disp. sum

/post1
plnsol,s,eqv,1,1 ! von Mises stres